{
  pkgs,
  ...
}:
let
  # Manjaro cursor theme.
  # Also known as Maia but exact same one without git history and wrong credits.
  # Not a big fan of Manjaro but that cursor theme slaps.
  menda = pkgs.stdenvNoCC.mkDerivation rec {
    pname = "menda-cursor";
    version = "2014-11-25";

    src = pkgs.fetchFromGitHub {
      owner = "anexation";
      repo = pname;
      rev = "e3503252cbac2772e800929d12341c6a3284cd15";
      hash = "sha256-CR/nfydRjMADdJ4iBP00O24XENC2jbsbwNk0w63G3h4=";
    };

    installPhase = ''
      runHook preInstall
      mkdir -p $out/share/icons
      mv Menda-Cursor $out/share/icons/menda-cursor
      runHook postInstall
    '';
  };
  # Phinger is also not a bad cursor theme, more geometric, has dark/light theme,
  # but overall same amount of cursor and not very green innit.

  # That being said, it doesn't seem that cursor change immediately on apply,
  # so my idea of dark cursor on light theme and vice-versa might not fly anyways.
in
{
  config = {
    home.pointerCursor = {
      name = "menda-cursor";
      package = menda;
      size = 32;
      gtk.enable = true;
    };
  };
}