{
  # nixpkgs ? <nixpkgs>,
  # nixpkgs ? builtins.getFlake "github:GeoffreyFrogeye/nixpkgs/zelbar",
  nixpkgs ? /nix/store/8g86qw3c2fr56bhhvqznrlic4jig9hb3-source,
  pkgs ? import nixpkgs {
    config = { };
    overlays = [ ];
  },
  ...
}:
# Tried using pyproject.nix but mpd2 dependency wouldn't resolve,
# is called pyton-mpd2 on PyPi but mpd2 in nixpkgs.
pkgs.python3Packages.buildPythonPackage rec {
  pname = "frobar";
  version = "4.0";

  dependencies = with pkgs.python3Packages; [
    i3ipc
    psutil
    pulsectl-asyncio
    pygobject3
    rich
  ];

  nativeBuildInputs = with pkgs; [
    wrapGAppsHook4
    gobject-introspection
  ];

  buildInputs = with pkgs; [
    playerctl
    gtk4-layer-shell
  ];

  preFixup = ''
    makeWrapperArgs+=(
      ''${gappsWrapperArgs[@]}
      --prefix PATH : ${
        pkgs.lib.makeBinPath (
          with pkgs;
          [
            wirelesstools
            zelbar
          ]
        )
      }
      --prefix LD_LIBRARY_PATH : ${LD_LIBRARY_PATH}
    )
  '';

  LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath [
    pkgs.glib.out
    pkgs.playerctl
    pkgs.gtk4-layer-shell
  ];

  src = ./.;
}