{
  pkgs,
  lib,
  config,
  ...
}:
let
  fringer-cursors = pkgs.stdenvNoCC.mkDerivation rec {
    pname = "fringer-cursors";
    version = "1.0";

    src = pkgs.fetchurl {
      url = "https://github.com/GeoffreyFrogeye/fringer-cursors/releases/download/v${version}/fringer-cursors-variants.tar.bz2";
      sha256 = "sha256-P4PhGTHto+DMn1VZ5ZvMWHYXWjHfw90GKBNDn908WgU=";
    };

    sourceRoot = ".";

    installPhase = ''
      runHook preInstall
      mkdir -p $out/share/icons
      cp -r ./fringer-cursors* $out/share/icons
      runHook postInstall
    '';

    meta = with lib; {
      description = "Modernized Menda cursor theme";
      homepage = "https://github.com/GeoffreyFrogeye/fringer-cursors";
      platforms = platforms.unix;
      license = licenses.cc-by-sa-40;
      maintainers = with maintainers; [ geoffreyfrogeye ];
    };
  };
in
{
  config = {
    stylix.cursor = {
      name = "fringer-cursors-${if config.stylix.polarity == "dark" then "light" else "dark"}";
      package = fringer-cursors;
      size = 32;
    };
  };
}