{ pkgs, config, lib, ... }:
let
  nixgl = import
    (builtins.fetchGit {
      url = "https://github.com/nix-community/nixGL";
      rev = "489d6b095ab9d289fe11af0219a9ff00fe87c7c5";
    })
    { };
  nixGLIntelPrefix = "${nixgl.nixVulkanIntel}/bin/nixVulkanIntel ${nixgl.nixGLIntel}/bin/nixGLIntel ";
  wmPrefix = "${lib.optionalString config.frogeye.desktop.nixGLIntel nixGLIntelPrefix}";
in
{
  imports = [
    ./frobar
  ];
  config = lib.mkIf config.frogeye.desktop.xorg {
    frogeye.shellAliases = {
      noise = ''${pkgs.sox}/bin/play -c 2 -n synth $'' + ''{1}noise'';
      beep = ''${pkgs.sox}/bin/play -n synth sine E5 sine A4 remix 1-2 fade 0.5 1.2 0.5 2> /dev/null'';

      # n = "$HOME/.config/i3/terminal & disown"; # Not used anymore since alacritty daemon mode doesn't preserve environment variables
      x = "startx ${config.home.homeDirectory}/${config.xsession.scriptPath}; logout";
      # TODO Is it possible to not start nvidia stuff on nixOS?
      # nx = "nvidia-xrun ${config.xsession.scriptPath}; sudo systemctl start nvidia-xrun-pm; logout";
    };
    xsession = {
      enable = true;
      # Not using config.xdg.configHome because it needs to be $HOME-relative paths and path manipulation is hard
      scriptPath = ".config/xsession";
      profilePath = ".config/xprofile";
      windowManager = {
        command = lib.mkForce "${wmPrefix} ${config.xsession.windowManager.i3.package}/bin/i3";
        i3 = {
          enable = true;
          config =
            let
              # lockColors = with config.lib.stylix.colors.withHashtag; { a = base00; b = base01; d = base00; }; # Black or White, depending on current theme
              # lockColors = with config.lib.stylix.colors.withHashtag; { a = base0A; b = base0B; d = base00; }; # Green + Yellow
              lockColors = { a = "#82a401"; b = "#466c01"; d = "#648901"; }; # Old
              lockSvg = pkgs.writeText "lock.svg" "<svg xmlns=\"http://www.w3.org/2000/svg\" viewBox=\"0 0 50 50\" height=\"50\" width=\"50\"><path fill=\"${lockColors.a}\" d=\"M0 50h50V0H0z\"/><path d=\"M0 0l50 50H25L0 25zm50 0v25L25 0z\" fill=\"${lockColors.d}\"/></svg>";
              lockPng = pkgs.runCommand "lock.png" { } "${pkgs.imagemagick}/bin/convert ${lockSvg} $out";
              locker = pkgs.writeShellScript "i3-locker"
                ''
                  # Remove SSH and GPG keys from keystores
                  ${pkgs.openssh}/bin/ssh-add -D
                  echo RELOADAGENT | ${pkgs.gnupg}/bin/gpg-connect-agent
                  ${pkgs.coreutils}/bin/rm -rf "/tmp/cached_pass_$UID"

                  ${pkgs.lightdm}/bin/dm-tool lock
                  # TODO Does that work for all DMs?
                  if [ $? -ne 0 ]; then
                      if [ -d ${config.xdg.cacheHome}/lockpatterns ]
                      then
                          pattern=$(${pkgs.findutils} ${config.xdg.cacheHome}/lockpatterns | sort -R | head -1)
                      else
                          pattern=${lockPng}
                      fi
                      revert() {
                          ${pkgs.xorg.xset}/bin/xset dpms 0 0 0
                      }
                      trap revert SIGHUP SIGINT SIGTERM
                      ${pkgs.xorg.xset}/bin/xset dpms 5 5 5
                      ${pkgs.i3lock}/bin/i3lock --nofork --color ${builtins.substring 1 6 lockColors.d} --image=$pattern --tiling --ignore-empty-password
                      revert
                  fi
                '';
              focus = "exec ${ pkgs.writeShellScript "i3-focus-window"
        ''
          WINDOW=`${pkgs.xdotool}/bin/xdotool getwindowfocus`
          eval `${pkgs.xdotool}/bin/xdotool getwindowgeometry --shell $WINDOW` # this brings in variables WIDTH and HEIGHT
          TX=`${pkgs.coreutils}/bin/expr $WIDTH / 2`
          TY=`${pkgs.coreutils}/bin/expr $HEIGHT / 2`
          ${pkgs.xdotool}/bin/xdotool mousemove -window $WINDOW $TX $TY
        ''
        }";
              mode_system = "[L] Vérouillage [E] Déconnexion [S] Veille [H] Hibernation [R] Redémarrage [P] Extinction";
              mode_resize = "Resize";
              mode_pres_main = "Presentation (main display)";
              mode_pres_sec = "Presentation (secondary display)";
              mode_screen = "Screen setup [A] Auto [L] Load [S] Save [R] Remove [D] Default";
              mode_temp = "Temperature [R] Red [D] Dust storm [C] Campfire [O] Normal [A] All nighter [B] Blue";
            in
            {
              modifier = "Mod4";
              terminal = "alacritty";
              colors = let ignore = "#ff00ff"; in
                with config.lib.stylix.colors.withHashtag; lib.mkForce {
                  focused = { border = base0B; background = base0B; text = base00; indicator = base00; childBorder = base0B; };
                  focusedInactive = { border = base02; background = base02; text = base05; indicator = base02; childBorder = base02; };
                  unfocused = { border = base05; background = base04; text = base00; indicator = base04; childBorder = base00; };
                  urgent = { border = base0F; background = base08; text = base00; indicator = base08; childBorder = base0F; };
                  placeholder = { border = ignore; background = base00; text = base05; indicator = ignore; childBorder = base00; };
                  background = base07;
                  # I set the color of the active tab as the the background color of the terminal so they merge together.
                };
              focus.followMouse = false;
              keybindings =
                let
                  mod = config.xsession.windowManager.i3.config.modifier;
                  rofi = "exec --no-startup-id ${config.programs.rofi.package}/bin/rofi";
                  pactl = "exec ${pkgs.pulseaudio}/bin/pactl"; # TODO Use NixOS package if using NixOS
                  screenshots_dir = config.xdg.userDirs.extraConfig.XDG_SCREENSHOTS_DIR;
                  scrot = "${pkgs.scrot}/bin/scrot --exec '${pkgs.coreutils}/bin/mv $f ${screenshots_dir}/ && ${pkgs.optipng}/bin/optipng ${screenshots_dir}/$f'";
                in
                {
                  # Compatibility layer for people coming from other backgrounds
                  "Mod1+Tab" = "${rofi} -modi window -show window";
                  "Mod1+F2" = "${rofi} -modi drun -show drun";
                  "Mod1+F4" = "kill";
                  # kill focused window
                  "${mod}+z" = "kill";
                  button2 = "kill";
                  # Rofi
                  "${mod}+c" = "exec --no-startup-id ${config.programs.rofi.pass.package}/bin/rofi-pass --last-used";
                  # TODO Try autopass.cr
                  # 23.11 config.programs.rofi.pass.package
                  "${mod}+i" = "exec --no-startup-id ${pkgs.rofimoji}/bin/rofimoji";
                  "${mod}+plus" = "${rofi} -modi ssh -show ssh";
                  "${mod}+ù" = "${rofi} -modi ssh -show ssh -ssh-command '{terminal} -e {ssh-client} {host} -t \"sudo -s -E\"'";
                  # TODO In which keyboard layout?
                  "${mod}+Tab" = "${rofi} -modi window -show window";
                  # start program launcher
                  "${mod}+d" = "${rofi} -modi run -show run";
                  "${mod}+Shift+d" = "${rofi} -modi drun -show drun";
                  # Start Applications
                  "${mod}+Return" = "exec ${
            pkgs.writeShellScript "terminal" "${config.programs.alacritty.package}/bin/alacritty msg create-window || exec ${config.programs.alacritty.package}/bin/alacritty -e zsh"
            # -e zsh is for systems where I can't configure my user's shell
            # TODO Is a shell script even required?
          }";
                  "${mod}+Shift+Return" = "exec ${config.programs.urxvt.package}/bin/urxvt";
                  "${mod}+p" = "exec ${pkgs.xfce.thunar}/bin/thunar";
                  "${mod}+m" = "exec ${config.programs.qutebrowser.package}/bin/qutebrowser --override-restore --backend=webengine";
                  # TODO --backend not useful anymore
                  # Volume control
                  "XF86AudioRaiseVolume" = "${pactl} set-sink-mute @DEFAULT_SINK@ false; ${pactl} set-sink-volume @DEFAULT_SINK@ +5%";
                  "XF86AudioLowerVolume" = "${pactl} set-sink-mute @DEFAULT_SINK@ false; ${pactl} set-sink-volume @DEFAULT_SINK@ -5%";
                  "XF86AudioMute" = "${pactl} set-sink-mute @DEFAULT_SINK@ true";
                  "${mod}+F7" = "${pactl} suspend-sink @DEFAULT_SINK@ 1; ${pactl} suspend-sink @DEFAULT_SINK@ 0"; # Re-synchronize bluetooth headset
                  "${mod}+F11" = "exec ${pkgs.pavucontrol}/bin/pavucontrol";
                  "${mod}+F12" = "exec ${pkgs.pavucontrol}/bin/pavucontrol";
                  # TODO Find pacmixer?
                  # Media control
                  "XF86AudioPrev" = "exec ${pkgs.mpc-cli}/bin/mpc prev";
                  "XF86AudioPlay" = "exec ${pkgs.mpc-cli}/bin/mpc toggle";
                  "XF86AudioNext" = "exec ${pkgs.mpc-cli}/bin/mpc next";
                  # Misc
                  "${mod}+F10" = "exec ${ pkgs.writeShellScript "show-keyboard-layout"
            ''
              layout=`${pkgs.xorg.setxkbmap}/bin/setxkbmap -query | ${pkgs.gnugrep}/bin/grep ^layout: | ${pkgs.gawk}/bin/awk '{ print $2 }'`
              ${pkgs.libgnomekbd}/bin/gkbd-keyboard-display -l $layout
            ''
            }";
                  # Screenshots
                  "Print" = "exec ${scrot} --focused";
                  "${mod}+Print" = "exec ${scrot}";
                  "Ctrl+Print" = "exec ${pkgs.coreutils}/bin/sleep 1 && ${scrot} --select";
                  # TODO Try using bindsym --release instead of sleep
                  # change focus
                  "${mod}+h" = "focus left; ${focus}";
                  "${mod}+j" = "focus down; ${focus}";
                  "${mod}+k" = "focus up; ${focus}";
                  "${mod}+l" = "focus right; ${focus}";
                  # move focused window
                  "${mod}+Shift+h" = "move left; ${focus}";
                  "${mod}+Shift+j" = "move down; ${focus}";
                  "${mod}+Shift+k" = "move up; ${focus}";
                  "${mod}+Shift+l" = "move right; ${focus}";
                  # workspace back and forth (with/without active container)
                  "${mod}+b" = "workspace back_and_forth; ${focus}";
                  "${mod}+Shift+b" = "move container to workspace back_and_forth; workspace back_and_forth; ${focus}";
                  # Change container layout
                  "${mod}+g" = "split h; ${focus}";
                  "${mod}+v" = "split v; ${focus}";
                  "${mod}+f" = "fullscreen toggle; ${focus}";
                  "${mod}+s" = "layout stacking; ${focus}";
                  "${mod}+w" = "layout tabbed; ${focus}";
                  "${mod}+e" = "layout toggle split; ${focus}";
                  "${mod}+Shift+space" = "floating toggle; ${focus}";
                  # Focus container
                  "${mod}+space" = "focus mode_toggle; ${focus}";
                  "${mod}+a" = "focus parent; ${focus}";
                  "${mod}+q" = "focus child; ${focus}";
                  # Switch to workspace
                  "${mod}+1" = "workspace 1; ${focus}";
                  "${mod}+2" = "workspace 2; ${focus}";
                  "${mod}+3" = "workspace 3; ${focus}";
                  "${mod}+4" = "workspace 4; ${focus}";
                  "${mod}+5" = "workspace 5; ${focus}";
                  "${mod}+6" = "workspace 6; ${focus}";
                  "${mod}+7" = "workspace 7; ${focus}";
                  "${mod}+8" = "workspace 8; ${focus}";
                  "${mod}+9" = "workspace 9; ${focus}";
                  "${mod}+0" = "workspace 10; ${focus}";
                  # TODO Prevent repetitions, see workspace assignation for example
                  #navigate workspaces next / previous
                  "${mod}+Ctrl+h" = "workspace prev_on_output; ${focus}";
                  "${mod}+Ctrl+l" = "workspace next_on_output; ${focus}";
                  "${mod}+Ctrl+j" = "workspace prev; ${focus}";
                  "${mod}+Ctrl+k" = "workspace next; ${focus}";
                  # Move to workspace next / previous with focused container
                  "${mod}+Ctrl+Shift+h" = "move container to workspace prev_on_output; workspace prev_on_output; ${focus}";
                  "${mod}+Ctrl+Shift+l" = "move container to workspace next_on_output; workspace next_on_output; ${focus}";
                  "${mod}+Ctrl+Shift+j" = "move container to workspace prev; workspace prev; ${focus}";
                  "${mod}+Ctrl+Shift+k" = "move container to workspace next; workspace next; ${focus}";
                  # move focused container to workspace
                  "${mod}+ctrl+1" = "move container to workspace 1; ${focus}";
                  "${mod}+ctrl+2" = "move container to workspace 2; ${focus}";
                  "${mod}+ctrl+3" = "move container to workspace 3; ${focus}";
                  "${mod}+ctrl+4" = "move container to workspace 4; ${focus}";
                  "${mod}+ctrl+5" = "move container to workspace 5; ${focus}";
                  "${mod}+ctrl+6" = "move container to workspace 6; ${focus}";
                  "${mod}+ctrl+7" = "move container to workspace 7; ${focus}";
                  "${mod}+ctrl+8" = "move container to workspace 8; ${focus}";
                  "${mod}+ctrl+9" = "move container to workspace 9; ${focus}";
                  "${mod}+ctrl+0" = "move container to workspace 10; ${focus}";
                  # move to workspace with focused container
                  "${mod}+shift+1" = "move container to workspace 1; workspace 1; ${focus}";
                  "${mod}+shift+2" = "move container to workspace 2; workspace 2; ${focus}";
                  "${mod}+shift+3" = "move container to workspace 3; workspace 3; ${focus}";
                  "${mod}+shift+4" = "move container to workspace 4; workspace 4; ${focus}";
                  "${mod}+shift+5" = "move container to workspace 5; workspace 5; ${focus}";
                  "${mod}+shift+6" = "move container to workspace 6; workspace 6; ${focus}";
                  "${mod}+shift+7" = "move container to workspace 7; workspace 7; ${focus}";
                  "${mod}+shift+8" = "move container to workspace 8; workspace 8; ${focus}";
                  "${mod}+shift+9" = "move container to workspace 9; workspace 9; ${focus}";
                  "${mod}+shift+0" = "move container to workspace 10; workspace 10; ${focus}";
                  # move workspaces to screen (arrow keys)
                  "${mod}+ctrl+shift+Right" = "move workspace to output right; ${focus}";
                  "${mod}+ctrl+shift+Left" = "move workspace to output left; ${focus}";
                  "${mod}+Ctrl+Shift+Up" = "move workspace to output above; ${focus}";
                  "${mod}+Ctrl+Shift+Down" = "move workspace to output below; ${focus}";
                  # i3 control
                  "${mod}+Shift+c" = "reload";
                  "${mod}+Shift+r" = "restart";
                  "${mod}+Shift+e" = "exit";
                  # Screen off commands
                  "${mod}+F1" = "exec --no-startup-id ${pkgs.bash}/bin/sh -c \"${pkgs.coreutils}/bin/sleep .25 && ${pkgs.xorg.xset}/bin/xset dpms force off\"";
                  # TODO --release?
                  "${mod}+F4" = "exec --no-startup-id ${pkgs.xautolock}/bin/xautolock -disable";
                  "${mod}+F5" = "exec --no-startup-id ${pkgs.xautolock}/bin/xautolock -enable";
                  # Modes
                  "${mod}+Escape" = "mode ${mode_system}";
                  "${mod}+r" = "mode ${mode_resize}";
                  "${mod}+Shift+p" = "mode ${mode_pres_main}";
                  "${mod}+t" = "mode ${mode_screen}";
                  "${mod}+y" = "mode ${mode_temp}";
                };
              modes = let return_bindings = {
                "Return" = "mode default";
                "Escape" = "mode default";
              }; in
                {
                  "${mode_system}" = {
                    "l" = "exec --no-startup-id exec ${locker}, mode default";
                    "e" = "exit, mode default";
                    "s" = "exec --no-startup-id exec ${locker} & ${pkgs.systemd}/bin/systemctl suspend --check-inhibitors=no, mode default";
                    "h" = "exec --no-startup-id exec ${locker} & ${pkgs.systemd}/bin/systemctl hibernate, mode default";
                    "r" = "exec --no-startup-id ${pkgs.systemd}/bin/systemctl reboot, mode default";
                    "p" = "exec --no-startup-id ${pkgs.systemd}/bin/systemctl poweroff -i, mode default";
                  } // return_bindings;
                  "${mode_resize}" = {
                    "h" = "resize shrink width 10 px or 10 ppt; ${focus}";
                    "j" = "resize grow height 10 px or 10 ppt; ${focus}";
                    "k" = "resize shrink height 10 px or 10 ppt; ${focus}";
                    "l" = "resize grow width 10 px or 10 ppt; ${focus}";
                  } // return_bindings;
                  "${mode_pres_main}" = {
                    "b" = "workspace 3, workspace 4, mode ${mode_pres_sec}";
                    "q" = "mode default";
                    "Return" = "mode default";
                  };
                  "${mode_pres_sec}" = {
                    "b" = "workspace 1, workspace 2, mode ${mode_pres_main}";
                    "q" = "mode default";
                    "Return" = "mode default";
                  };
                  "${mode_screen}" =
                    let
                      builtin_configs = [ "off" "common" "clone-largest" "horizontal" "vertical" "horizontal-reverse" "vertical-reverse" ];
                      autorandrmenu = { title, option, builtin ? false }: pkgs.writeShellScript "autorandrmenu"
                        ''
                          shopt -s nullglob globstar
                          profiles="${if builtin then lib.strings.concatLines builtin_configs else ""}$(${pkgs.autorandr}/bin/autorandr | ${pkgs.gawk}/bin/awk '{ print $1 }')"
                          profile="$(echo "$profiles" | ${config.programs.rofi.package}/bin/rofi -dmenu -p "${title}")"
                          [[ -n "$profile" ]] || exit
                          ${pkgs.autorandr}/bin/autorandr ${option} "$profile"
                        '';
                    in
                    {
                      "a" = "exec ${pkgs.autorandr}/bin/autorandr --change --force, mode default";
                      "l" = "exec ${autorandrmenu {title="Load profile"; option="--load"; builtin = true;}}, mode default";
                      "s" = "exec ${autorandrmenu {title="Save profile"; option="--save";}}, mode default";
                      "r" = "exec ${autorandrmenu {title="Remove profile"; option="--remove";}}, mode default";
                      "d" = "exec ${autorandrmenu {title="Default profile"; option="--default"; builtin = true;}}, mode default";
                    } // return_bindings;
                  "${mode_temp}" = {
                    "r" = "exec ${pkgs.sct}/bin/sct 1000";
                    "d" = "exec ${pkgs.sct}/bin/sct 2000";
                    "c" = "exec ${pkgs.sct}/bin/sct 4500";
                    "o" = "exec ${pkgs.sct}/bin/sct";
                    "a" = "exec ${pkgs.sct}/bin/sct 8000";
                    "b" = "exec ${pkgs.sct}/bin/sct 10000";
                  } // return_bindings;
                };
              window = {
                hideEdgeBorders = "both";
                titlebar = false; # So that single-container screens are basically almost fullscreen
                commands = [
                  # Open specific applications in floating mode
                  { criteria = { class = "Firefox"; }; command = "layout tabbed"; } # Doesn't seem to work anymore
                  { criteria = { class = "qutebrowser"; }; command = "layout tabbed"; }
                  { criteria = { title = "^pdfpc.*"; window_role = "presenter"; }; command = "move to output left, fullscreen"; }
                  { criteria = { title = "^pdfpc.*"; window_role = "presentation"; }; command = "move to output right, fullscreen"; }
                  # switch to workspace with urgent window automatically
                  { criteria = { urgent = "latest"; }; command = "focus"; }
                ];
              };
              floating = {
                criteria = [
                  { title = "pacmixer"; }
                  { window_role = "pop-up"; }
                  { window_role = "task_dialog"; }
                ];
              };
              startup = [
                # Lock screen after 10 minutes
                { notification = false; command = "${pkgs.xautolock}/bin/xautolock -time 10 -locker '${pkgs.xorg.xset}/bin/xset dpms force standby' -killtime 1 -killer ${locker}"; }
                {
                  notification = false;
                  command = "${pkgs.writeShellApplication {
            name = "batteryNotify";
            runtimeInputs = with pkgs; [coreutils libnotify];
            text = builtins.readFile ./batteryNotify.sh;
            # TODO Use batsignal instead?
            # TODO Only on computers with battery
          }}/bin/batteryNotify";
                }
                # TODO There's a services.screen-locker.xautolock but not sure it can match the above command
              ];
              workspaceLayout = "tabbed";
              focus.mouseWarping = true; # i3 only supports warping to workspace, hence ${focus}
              workspaceOutputAssign =
                let
                  x11_screens = config.frogeye.desktop.x11_screens;
                  workspaces = map (i: { name = toString i; key = toString (lib.mod i 10); }) (lib.lists.range 1 10);
                  forEachWorkspace = f: map (w: f { w = w; workspace = ((builtins.elemAt workspaces w)); }) (lib.lists.range 0 ((builtins.length workspaces) - 1));
                in
                forEachWorkspace ({ w, workspace }: { output = builtins.elemAt x11_screens (lib.mod w (builtins.length x11_screens)); workspace = workspace.name; });
            };
        };
      };
      numlock.enable = config.frogeye.desktop.numlock;
    };

    programs = {
      # Browser
      qutebrowser = {
        enable = true;
        keyBindings = {
          normal = {
            # Match tab behaviour to i3. Not that I use them.
            "H" = "tab-prev";
            "J" = "back";
            "K" = "forward";
            "L" = "tab-next";
            # "T" = null;
            "af" = "spawn --userscript freshrss"; # TODO Broken?
            "as" = "spawn --userscript shaarli"; # TODO I don't use shaarli anymore
            # "d" = null;
            "u" = "undo --window";
            # TODO Unbind d and T (?)
          };
        };
        loadAutoconfig = true;
        searchEngines = rec {
          DEFAULT = ecosia;
          alpinep = "https://pkgs.alpinelinux.org/packages?name={}&branch=edge";
          ampwhat = "http://www.amp-what.com/unicode/search/{}";
          arch = "https://wiki.archlinux.org/?search={}";
          archp = "https://www.archlinux.org/packages/?q={}";
          aur = "https://aur.archlinux.org/packages/?K={}";
          aw = ampwhat;
          ddg = duckduckgo;
          dockerhub = "https://hub.docker.com/search/?isAutomated=0&isOfficial=0&page=1&pullCount=0&q={}&starCount=0";
          duckduckgo = "https://duckduckgo.com/?q={}&ia=web";
          ecosia = "https://www.ecosia.org/search?q={}";
          gfr = "https://www.google.fr/search?hl=fr&q={}";
          g = google;
          gh = github;
          gi = "http://images.google.com/search?q={}";
          giphy = "https://giphy.com/search/{}";
          github = "https://github.com/search?q={}";
          google = "https://www.google.fr/search?q={}";
          invidious = "https://invidious.frogeye.fr/search?q={}";
          inv = invidious;
          npm = "https://www.npmjs.com/search?q={}";
          q = qwant;
          qwant = "https://www.qwant.com/?t=web&q={}";
          wolfram = "https://www.wolframalpha.com/input/?i={}";
          youtube = "https://www.youtube.com/results?search_query={}";
          yt = youtube;
        };
        settings = {
          downloads.location.prompt = false;
          tabs = {
            show = "never";
            tabs_are_windows = true;
          };
          url = rec {
            open_base_url = true;
            start_pages = lib.mkDefault "https://geoffrey.frogeye.fr/blank.html";
            default_page = start_pages;
          };
          content = {
            # I had this setting below, not sure if it did something special
            # config.set("content.cookies.accept", "no-3rdparty", "chrome://*/*")
            cookies.accept = "no-3rdparty";
            prefers_reduced_motion = true;
            headers.accept_language = "fr-FR, fr;q=0.9, en-GB;q=0.8, en-US;q=0.7, en;q=0.6";
            tls.certificate_errors = "ask-block-thirdparty";
          };
          editor.command = [ "${pkgs.neovide}/bin/neovide" "--" "-f" "{file}" "-c" "normal {line}G{column0}l" ];
          # TODO Doesn't work on Arch. Does it even load the right profile on Nix?
          # TODO spellcheck.languages = ["fr-FR" "en-GB" "en-US"];

        };
      };

      # Terminal
      alacritty = {
        # TODO Emojis. Or maybe they work on NixOS?
        # Arch (working) shows this with alacritty -vvv:
        # [TRACE] [crossfont] Got font path="/usr/share/fonts/twemoji/twemoji.ttf", index=0
        # [DEBUG] [crossfont] Loaded Face Face { ft_face: Font Face: Regular, load_flags: MONOCHROME | TARGET_MONO | COLOR, render_mode: "Mono", lcd_filter: 1 }
        # Nix (not working) shows this:
        # [TRACE] [crossfont] Got font path="/nix/store/872g3w9vcr5nh93r0m83a3yzmpvd2qrj-home-manager-path/share/fonts/truetype/TwitterColorEmoji-SVGinOT.ttf", index=0
        # [DEBUG] [crossfont] Loaded Face Face { ft_face: Font Face: Regular, load_flags: TARGET_LIGHT | COLOR, render_mode: "Lcd", lcd_filter: 1 }

        enable = true;
        settings = {
          bell = {
            animation = "EaseOutExpo";
            color = "#000000";
            command = { program = "${pkgs.sox}/bin/play"; args = [ "-n" "synth" "sine" "C5" "sine" "E4" "remix" "1-2" "fade" "0.1" "0.2" "0.1" ]; };
            duration = 100;
          };
          cursor = { vi_mode_style = "Underline"; };
          env = {
            WINIT_X11_SCALE_FACTOR = "1";
            # Prevents Alacritty from resizing from one monitor to another.
            # Might cause issue on HiDPI screens but we'll get there when we get there
          };
          hints = {
            enabled = [
              {
                binding = { mods = "Control|Alt"; key = "F"; };
                command = "${pkgs.xdg-utils}/bin/xdg-open";
                mouse = { enabled = true; mods = "Control"; };
                post_processing = true;
                regex = "(mailto:|gemini:|gopher:|https:|http:|news:|file:|git:|ssh:|ftp:)[^\\u0000-\\u001F\\u007F-\\u009F<>\"\\\\s{-}\\\\^⟨⟩`]+";
              }
            ];
          };
          key_bindings = [
            { mode = "~Search"; mods = "Alt|Control"; key = "Space"; action = "ToggleViMode"; }
            { mode = "Vi|~Search"; mods = "Control"; key = "K"; action = "ScrollHalfPageUp"; }
            { mode = "Vi|~Search"; mods = "Control"; key = "J"; action = "ScrollHalfPageDown"; }
            { mode = "~Vi"; mods = "Control|Alt"; key = "V"; action = "Paste"; }
            { mods = "Control|Alt"; key = "C"; action = "Copy"; }
            { mode = "~Search"; mods = "Control|Alt"; key = "F"; action = "SearchForward"; }
            { mode = "~Search"; mods = "Control|Alt"; key = "B"; action = "SearchBackward"; }
            { mode = "Vi|~Search"; mods = "Control|Alt"; key = "C"; action = "ClearSelection"; }
          ];
          window = {
            dynamic_padding = false;
            dynamic_title = true;
          };
        };
      };
      # Backup terminal
      urxvt = {
        enable = true;
        package = pkgs.rxvt-unicode-emoji;
        scroll = {
          bar.enable = false;
        };
        iso14755 = false; # Disable Ctrl+Shift default bindings
        keybindings = {
          "Shift-Control-C" = "eval:selection_to_clipboard";
          "Shift-Control-V" = "eval:paste_clipboard";
          # TODO Not sure resizing works, Nix doesn't have the package (urxvt-resize-font-git on Arch)
          "Control-KP_Subtract" = "resize-font:smaller";
          "Control-KP_Add" = "resize-font:bigger";
        };
        extraConfig = {
          "letterSpace" = 0;
          "perl-ext-common" = "resize-font,bell-command,readline,selection";
          "bell-command" = "${pkgs.sox}/bin/play -n synth sine C5 sine E4 remix 1-2 fade 0.1 0.2 0.1 &> /dev/null";
        };
      };
      rofi = {
        # TODO This theme template, that was used for Arch, looks much better:
        # https://gitlab.com/jordiorlando/base16-rofi/-/blob/master/templates/default.mustache
        enable = true;
        pass.enable = true;
        extraConfig = {
          lazy-grab = false;
          matching = "regex";
        };
      };
      autorandr = {
        enable = true;
        hooks.postswitch = {
            background = "${pkgs.feh}/bin/feh --no-fehbg --bg-fill ${config.stylix.image}";
        };
      };
      mpv = {
        enable = true;
        config = {
          audio-display = false;
          save-position-on-quit = true;
          osc = false; # # Required by thumbnail script
        };
        scripts = with pkgs.mpvScripts; [ thumbnail ];
        scriptOpts = {
          mpv_thumbnail_script = {
            cache_directory = "/tmp/mpv_thumbs_${config.home.username}";
          };
        };
      };
    };

    xdg = {
      mimeApps = {
        enable = true;
        associations.added = {
          "text/html" = "org.qutebrowser.qutebrowser.desktop";
          "x-scheme-handler/http" = "org.qutebrowser.qutebrowser.desktop";
          "x-scheme-handler/https" = "org.qutebrowser.qutebrowser.desktop";
          "x-scheme-handler/about" = "org.qutebrowser.qutebrowser.desktop";
          "x-scheme-handler/unknown" = "org.qutebrowser.qutebrowser.desktop";
        };
      };
      userDirs = {
        enable = true; # TODO Which ones do we want?
        createDirectories = true;
        # French, because then it there's a different initial for each, making navigation easier
        desktop = null;
        download = "${config.home.homeDirectory}/Téléchargements";
        music = "${config.home.homeDirectory}/Musiques";
        pictures = "${config.home.homeDirectory}/Images";
        publicShare = null;
        templates = null;
        videos = "${config.home.homeDirectory}/Vidéos";
        extraConfig = {
          XDG_SCREENSHOTS_DIR = "${config.home.homeDirectory}/Screenshots";
        };
      };
      configFile = {
        "pulse/client.conf" = {
          text = ''cookie-file = .config/pulse/pulse-cookie'';
        };
        "rofimoji.rc" = {
          text = ''
            skin-tone = neutral
            files = [emojis, math]
            action = clipboard
          '';
        };
        "vimpc/vimpcrc" = {
          text = ''
            map FF :browse<C-M>gg/
            map à :set add next<C-M>a:set add end<C-M>
            map @ :set add next<C-M>a:set add end<C-M>:next<C-M>
            map ° D:browse<C-M>A:shuffle<C-M>:play<C-M>:playlist<C-M>
            set songformat {%a - %b: %t}|{%f}$E$R $H[$H%l$H]$H
            set libraryformat %n \| {%t}|{%f}$E$R $H[$H%l$H]$H
            set ignorecase
            set sort library
          '';
        };
      };
    };
    services = {
      unclutter.enable = true;
      dunst =
        {
          enable = true;
          settings =
            # TODO Change dmenu for rofi, so we can use context
            with config.lib.stylix.colors.withHashtag; {
              global = {
                separator_color = lib.mkForce base05;
                idle_threshold = 120;
                markup = "full";
                max_icon_size = 48;
                # TODO Those shortcuts don't seem to work, maybe try:
                # > define shortcuts inside your window manager and bind them to dunstctl(1) commands
                close_all = "ctrl+mod4+n";
                close = "mod4+n";
                context = "mod1+mod4+n";
                history = "shift+mod4+n";
              };

              urgency_low = {
                background = lib.mkForce base01;
                foreground = lib.mkForce base03;
                frame_color = lib.mkForce base05;
              };
              urgency_normal = {
                background = lib.mkForce base02;
                foreground = lib.mkForce base05;
                frame_color = lib.mkForce base05;
              };
              urgency_critical = {
                background = lib.mkForce base08;
                foreground = lib.mkForce base06;
                frame_color = lib.mkForce base05;
              };
            };
        };
      mpd = {
        enable = true;
        network = {
          listenAddress = "0.0.0.0"; # So it can be controlled from home
          # TODO ... and whoever is the Wi-Fi network I'm using, which, not great
          startWhenNeeded = true;
        };
        extraConfig = ''
          restore_paused "yes"
        '';
      };
      autorandr.enable = true;
    };

    home = {
      packages = with pkgs; [
        # remote
        tigervnc

        # music
        mpc-cli
        ashuffle
        vimpc

        # multimedia common
        gimp
        inkscape
        libreoffice

        # data management
        freefilesync

        # browsers
        firefox

        # fonts
        dejavu_fonts
        twemoji-color-font
        gnome.gedit
        feh
        zbar
        zathura
        meld
        python3Packages.magic

        # x11-exclusive
        numlockx
        simplescreenrecorder
        trayer
        xclip
        keynav
        xorg.xinit
        xorg.xbacklight
        # TODO Make this clean. Service?


        # organisation
        pass
        thunderbird
      ];
      sessionVariables = {
        MPD_PORT = "${toString config.services.mpd.network.port}";
        ALSA_PLUGIN_DIR = "${pkgs.alsa-plugins}/lib/alsa-lib"; # Fixes an issue with sox (Cannot open shared library libasound_module_pcm_pulse.so)
        # UPST Patch this upstream like: https://github.com/NixOS/nixpkgs/blob/216b111fb87091632d077898df647d1438fc2edb/pkgs/applications/audio/espeak-ng/default.nix#L84
      };
    };
  };
}