dotfiles/hm/style.nix

{ pkgs, config, lib, ... }:
let
  # Currently last commit in https://github.com/danth/stylix/pull/194
  phases = [
    { command = "jour"; polarity = "light"; }
    { command = "crepuscule"; polarity = "dark"; }
    { command = "nuit"; polarity = "dark"; }
  ];
  cfg = config.frogeye.desktop.phasesBrightness;
in
{
  stylix = {

    base16Scheme = "${pkgs.base16-schemes}/share/themes/solarized-${config.frogeye.polarity}.yaml";
    image = builtins.fetchurl {
      url = "https://get.wallhere.com/photo/sunlight-abstract-minimalism-green-simple-circle-light-leaf-wave-material-line-wing-computer-wallpaper-font-close-up-macro-photography-124350.png";
      sha256 = "sha256:1zfq3f3v34i45mi72pkfqphm8kbhczsg260xjfl6dbydy91d7y93";
    };
    # The background is set on some occasions, autorandr + feh do the rest

    fonts = {
      monospace = {
        package = pkgs.nerdfonts.override {
          fonts = [ "DejaVuSansMono" ]; # Choose from https://github.com/NixOS/nixpkgs/blob/6ba3207643fd27ffa25a172911e3d6825814d155/pkgs/data/fonts/nerdfonts/shas.nix
        };
        name = "DejaVuSansM Nerd Font";
      };
    };
  };


  # Fix https://nix-community.github.io/home-manager/index.html#_why_do_i_get_an_error_message_about_literal_ca_desrt_dconf_literal_or_literal_dconf_service_literal
  # home.packages = [ pkgs.dconf ];
  dconf.enable = false; # Otherwise standalone home-manager complains it can't find /etc/dbus-1/session.conf on Arch.
  # Symlinking it to /usr/share/dbus-1/session.conf goes further but not much.

  home.packages = map
    (phase: (pkgs.writeShellApplication {
      name = "${phase.command}";
      runtimeInputs = [ pkgs.brightnessctl ];
      text = (lib.optionalString cfg.enable ''
        brightnessctl set ${builtins.getAttr phase.command cfg}
      '') + ''
        switch="/nix/var/nix/profiles/system/specialisation/${phase.polarity}/bin/switch-to-configuration"
        if [ -x "$switch" ]
        then
            # In two steps to get the visual changes slightly earlier
            sudo "$switch" test
            sudo "$switch" boot
        fi
      '';
    })
    )
    phases;
}