dotfiles/os/desktop.nix

{ pkgs, lib, config, ... }:
{
  config = lib.mkIf config.frogeye.desktop.xorg {
    # Enable the X11 windowing system

    services = {
      blueman.enable = true;
      xserver = {
        enable = true;
        windowManager.i3.enable = true;
        displayManager.defaultSession = "none+i3";

        # Keyboard layout
        extraLayouts.qwerty-fr = {
          description = "QWERTY-fr";
          languages = [ "fr" ];
          symbolsFile = "${pkgs.stdenv.mkDerivation {
          name = "qwerty-fr-keypad";
          src = builtins.fetchGit {
            url = "https://github.com/qwerty-fr/qwerty-fr.git";
            rev = "3a4d13089e8ef016aa20baf6b2bf3ea53de674b8";
          };
          patches = [ ./qwerty-fr-keypad.diff ];
          # TODO This doesn't seem to be applied... it's the whole point of the derivation :(
          installPhase = ''
            runHook preInstall
            mkdir -p $out/linux
            cp $src/linux/us_qwerty-fr $out/linux
            runHook postInstall
          '';
      }}/linux/us_qwerty-fr";
        };
        layout = "qwerty-fr";
      };
    };

    # Enable sound & bluetooth
    sound.enable = true;
    hardware = {
        bluetooth.enable = true;
        pulseaudio.enable = true;
        # TODO Try pipewire
    };

    # UPST
    # TODO Find a way to override packages either at NixOS level or HM level depending on what is used
    nixpkgs.overlays = [
      (final: prev: {
        sct = prev.sct.overrideAttrs
          (old: {
            patches = (old.patches or [ ]) ++ [
              ./sct_aarch64.patch
            ];
          });
      })
    ];
  };
}